BCI NET 2/BCI NET 2.iso/archives/utilities/cdrom/dockcdx.lha/CDRemote/CDPilot.rexx

OS/2 REXX Batch file | 1995-01-14 | 1.3 KB | 61 lines

/*
   Pilots the CDX.device through ARexx for Audio access

   Written by Yves Perrenoud  <[e-mail]>
                              <[e-mail]>
*/

Options results
Address CDX650

Parse Arg arg1 arg2
argu = upper(arg1)
skipsect = 75*20

Select
    When argu == "PLAYFIRST" Then 'CDPLAYTRACKS 1 0'
    When argu == "PLAY" Then 'CDPLAYTRACKS '||arg2||' 0'
    When argu == "STOP" Then 'CDSTOP'
    When argu == "PAUSE" Then
    Do
        'CDSTATUS'
        Select
            When result == "Playing" Then 'CDPAUSE'
            When result == "Paused" Then 'CDRESUME'
            Otherwise
        End
    End
    When argu == "EJECT" Then
    Do
        'CDSTATUS'
        If result ~= "No disc" Then 'CDEJECT'
    End
    When argu == "PLAYNEXT" Then
    Do
        'CDCURRENTLOC'
        Parse Var result track trash
        'CDNUMTRACKS'
        If track < result Then 'CDPLAYTRACKS '||track+1||' 0'
    End
    When argu == "PLAYPREVIOUS" Then
    Do
        'CDCURRENTLOC'
        Parse Var result track trash
        If track > 1 Then 'CDPLAYTRACKS '||track-1||' 0'
    End
    When argu == "FORWARD" Then
    Do
        'CDCURRENTLOC'
        Parse Var result track index discloc trackloc
        'CDLEADOUT'
        If discloc+skipsect <= result Then 'CDSKIPFWD '||skipsect
    End
    When argu == "REVERSE" Then
    Do
        'CDCURRENTLOC'
        Parse Var result track index discloc trackloc
        If discloc-skipsect >= 0 Then 'CDSKIPRVS '||skipsect
    End
    Otherwise
End